Exclusion Criteria

[jamesmartinn]

Hi,

I have data that has the following lay out:

Teacher  Student   Service   Date
smith     john       tutoring   mar312005
smith     john       reading    mar312005
smith     john       spelling    mar312005
smith     sally       tutoring    mar312005
smith     sarah      reading   mar312005

What I'd like to do is exclude a students entire case if they have a specific service requested. For example, my criteria of exclusion is reading. Therefore, I'd like to remove the reading entries for both students John and Sarah. however, John as you can see had two additional services provided on the same date (tutoring and spelling). I'd also like to remove these two entries as they are associated with the exclusion criteria.

The data are in long format. Teachers can see more than 1 student a day. A student can request more than 1 service in a visit. Again, I'd like to remove the students entire entry for that specific date / teacher combination if they had the exclusion critera.

any tips?

best,

edit: i've started by identifying my exclusion critera. I've output to a separate dataset all entries of the exlcusion criteria. I now have to do some kind of a careful merge back with the original dataset to exclude the entries that are not exlcusion criteria directly, but were associated with it (i.e, same student, same teacher and same date, different service)

[Mean Joe]

I've found this is real easy once you stop trying to be elegant, and just use two data steps.

*Identify the teacher/date records to eliminate: associated with reading;
data eliminates;
  set yourdata;
  if upcase(service)="READING";
  keep teacher student date;
run;

*Reduce YOURDATA set;
proc sort data=yourdata; by teacher student date; run;
proc sort data=eliminates nodupkey; by teacher student date; run;

data yournewdata;
  merge yourdata(in=a) eliminates(in=b);
  by teacher student date;
  if (not b);
run;

Alternatively, if you already have a dataset with exclusions that are more complicated than just service="reading", you can make the eliminates dataset like

data eliminates;
  merge yourdata(in=a) exclusions(in=b);
  by service;
  if a and b;
  keep teacher student date;
run;

I've done stuff like this before using retain statements, delete flags, and sorting...but it's really simple like this.

[jamesmartinn]

Thanks Joe!

You are absolutely right. I did try to be fancy (or efficient) in my coding and I think it really inhibited my progress. I started from scractch and went the datastep route using a contrived dataset. I was able to get the results I needed and our code is very similar!

Thank you so much for the reply - it is much appreciated!

Cheers,